-------------------------------------------------------------------------
-- Project: JCPU, a portable 8-bit RISC CPU written in VHDL
-- This file: cpu_embedded using cpu_core and rom
--
-- Copyright (C) 2007 J. Ahrensfeld
--
-- This program is free software: you can redistribute it and/or modify
-- it under the terms of the GNU General Public License as published by
-- the Free Software Foundation, either version 3 of the License, or
-- (at your option) any later version.
--
-- This program is distributed in the hope that it will be useful,
-- but WITHOUT ANY WARRANTY; without even the implied warranty of
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
-- GNU General Public License for more details.
--
-- You should have received a copy of the GNU General Public License
-- along with this program.  If not, see <http://www.gnu.org/licenses/>.
--
-- For questions and ideas, please contact the author at jens@jayfield.org
--
--------------------------------------------------------------------------

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.numeric_std.ALL;

entity tb_juart_tx_rx is
end;

architecture behave of tb_juart_tx_rx is

	-- Number of user data words for simulation
	constant CLK_PERIOD		: time := 10 ns;
	constant BAUD_DIV		: natural := 2;

	-- Common
	signal rst				: std_logic := '1';  
	signal clk				: std_logic := '1';  
	signal en_16_x_baud		: std_logic := '1';  
	
	-- TX
	signal tx_we			: std_logic := '0';  
	signal ser_out			: std_logic;  
	signal Tx_complete		: std_logic;  
	signal tx_din			: unsigned(7 downto 0) := (others => '0');

	-- RX
	signal ser_in			: std_logic := '1';  
	signal rx_dout_vld		: std_logic;  
	signal rx_dout			: unsigned(7 downto 0);
	
	-- Others
	signal baud_count		: unsigned(15 downto 0);
	signal baud_reg			: unsigned(15 downto 0) := to_unsigned(BAUD_DIV-1, baud_count'length);
	signal data_rx			: unsigned(7 downto 0);
	signal data_tx			: unsigned(7 downto 0);
	
begin

	ser_in	<= ser_out;
	
inst_juart_tx : entity work.juart_tx
	PORT MAP
	(
		rst					=> rst,
		clk					=> clk,
		we					=> tx_we,
		din					=> tx_din,
		en_16_x_baud		=> en_16_x_baud,
		Tx_complete			=> Tx_complete,
		ser_out				=> ser_out
	);

inst_juart_rx : entity work.juart_rx
	PORT MAP
	(
		rst					=> rst,
		clk					=> clk,
		en_16_x_baud		=> en_16_x_baud,
		dout_vld			=> rx_dout_vld,
		dout				=> rx_dout,
		ser_in				=> ser_in
	);

CLK_GEN: process
	begin
		wait for CLK_PERIOD/2;
		clk <= not clk;
	end process;

PROC_DATAREG_RX: process
	begin
		wait until rising_edge(clk) and rx_dout_vld = '1';
		data_rx <= rx_dout;
		assert rx_dout = data_tx report "Data mismatch" severity failure;
	end process;

PROC_DATAREG_TX: process
	begin
		wait until rising_edge(clk) and tx_we = '1';
		data_tx <= tx_din;
	end process;

baud_timer:
process(clk)
begin
	if rising_edge(clk) then
		en_16_x_baud <= '0';
		if rst = '1' then
			baud_count <= (others => '0');
		elsif baud_count = baud_reg then
			baud_count <= (others => '0');
			en_16_x_baud <= '1';
		else
			baud_count <= baud_count + 1;
		end if;
	end if;
end process;

------------------------------------------------------------------------------------------

STIMULUS: process


	begin

		wait for 3*CLK_PERIOD;
		rst <= '0';
		wait for 3*CLK_PERIOD;
		wait until rising_edge(clk);
		
		for i in 0 to 255 loop
			wait until rising_edge(clk) and Tx_complete = '1';
			tx_din <= to_unsigned(i, 8);
			tx_we <= '1';
			wait until rising_edge(clk) and Tx_complete = '0';
			tx_we <= '0';
		end loop;
		wait; 
	
	end process;
	
end architecture behave;
